3D Grid-based movement

Tagged: mojo3d

This topic contains 7 replies, has 3 voices, and was last updated by Mark Sibly 1 year, 2 months ago.

Viewing 8 posts - 1 through 8 (of 8 total)

Author

Posts

August 2, 2017 at 1:27 am #9658

impixi

Participant

A “simple” demo of grid-based movement through a 3D maze. (Trying to simulate the old Dungeon Master / Eye of the Beholder style of movement).

EDIT (28 Jan 2018): Numerous fixes so code compiles with latest mojo3d.

#rem

3d grid-based movement within a procedurally generated maze.

#end

#Import "<std>"
#Import "<mojo>"
#Import "<mojo3d>"

Using libc..		
Using std..
Using mojo..
Using mojo3d..

Function Main()
	New AppInstance
	New MyWindow("Retro Dungeon Test", 1024, 768, WindowFlags.Fullscreen)	
	App.Run()
End


' --- MOJO WINDOW ----------------------


Class MyWindow Extends Window
	
	Field _scene:Scene
	Field _light:Light

	Field _retroCam:RetroCam
	
	Field _keyBinder:KeyBinder
	
	Field _world3d:World3d

	Method New( title:String="Simple mojo app",width:Int=1024,height:Int=768,flags:WindowFlags = WindowFlags.Resizable | WindowFlags.HighDPI)

		Super.New( title,width,height,flags )
		
		_scene = Scene.GetCurrent()	
		_scene.ClearColor = Color.Black
		_scene.AmbientLight = Color.DarkGrey	
			
		'The black fog provides atmosphere and hides the 'pop-in' effect of visible/hidden cells.		
		
		_scene.FogColor = Color.Black
		_scene.FogNear = Cell3d.CellSize.X
		_scene.FogFar = Cell3d.CellSize.X * 3
		
		_keyBinder = New KeyBinder()
		_retroCam = New RetroCam(_scene)
			
		'The light is not yet properly functional.
		_light=New Light(_retroCam.Camera)
		_light.Color = Color.Orange
		_light.Type = LightType.Directional
		_light.Range = Cell3d.CellSize.X * 4.0
		
		SeedRnd(Microsecs()) 
						
		Generate()

	End

	Method Generate:Void()
		
		Print "Generating maze. Please wait."

		Local ms:=Millisecs()

		'32 columns and 32 rows.
		_world3d = New World3d(32, 32, _scene)

		Print "Generation time (millisecs): " + String(Millisecs() - ms)
		
		'3d cells, starting column and row, and a facing direction.
		_retroCam.SetCells3d(_world3d.Cells, 1, 1, Dir.North)
		
	End

	Method OnUpdate:Void()
		
		HandleKeys()					
		HandleMouse()
		
		_retroCam.Update()

	End

	Method HandleMouse:Void()
	
		If Mouse.Wheel.Y <> 0
			'Look up and down.
			_retroCam.DoPitch(Float(Mouse.Wheel.Y) * 10)
		Endif 
		
		If Mouse.ButtonDown(MouseButton.Middle)
			'Reset the pitch.
			_retroCam.ResetPitch()
		Elseif Mouse.ButtonDown(MouseButton.Left)
			If Not _retroCam.Moving And Not _retroCam.Turning

				'Left click on screen/window edges will move or turn depending on mouse location.

				If Mouse.Location.X < (0.1 * Width)
					If Mouse.Location.Y > Height - (0.2 * Height)
						_retroCam.StrafeLeft()
					Else
						_retroCam.DoCameraTurn(True)
					EndIf
				Elseif Mouse.Location.X > Width - (0.1 * Width)
					If Mouse.Location.Y > Height - (0.2 * Height)
						_retroCam.StrafeRight()
					Else
						_retroCam.DoCameraTurn(False)
					EndIf
				Elseif Mouse.Location.Y < (0.1 * Height)
					_retroCam.MoveForward()
				Elseif Mouse.Location.Y > Height - (0.1 * Height)
					_retroCam.MoveBack()		
				Endif
			Endif
		Endif
	
	End
	
	Method HandleKeys:Void()
		
		If Not _keyBinder Then Return
		
		'Only process input if camera not moving or turning.
		
		If (Not _retroCam.Moving) And (Not _retroCam.Turning)

			If Keyboard.KeyDown(_keyBinder.Get(Command.ExitGame))
				App.Terminate()
			Endif
					
			If Keyboard.KeyDown(_keyBinder.Get(Command.TurnLeft)) 
				_retroCam.DoCameraTurn(True)
				Return
			Elseif Keyboard.KeyDown(_keyBinder.Get(Command.TurnRight)) 
				_retroCam.DoCameraTurn(False)
				Return
			Endif
	
			If Keyboard.KeyDown(_keyBinder.Get(Command.MoveForward))
				_retroCam.MoveForward()
				Return
			Endif
	
			If Keyboard.KeyDown(_keyBinder.Get(Command.MoveBack))
				_retroCam.MoveBack()
				Return
			Endif
	
			If Keyboard.KeyDown(_keyBinder.Get(Command.StrafeRight))
				_retroCam.StrafeRight()
				Return
			Endif
				
			If Keyboard.KeyDown(_keyBinder.Get(Command.StrafeLeft))	
				_retroCam.StrafeLeft()
				Return
			Endif

			If Keyboard.KeyDown(_keyBinder.Get(Command.Generate))
				Generate()
			Endif

		Endif
		
	End

	Method OnRender:Void(canvas:Canvas) Override
	
		RequestRender()
		
		'******	
		OnUpdate()	
		'******	
		
		_scene.Update()
		_retroCam.Camera.Render(canvas)	
			
		'_scene.Render(canvas, _retroCam.Camera)
			
		canvas.DrawText("FPS: "+ App.FPS, 10, 10)
		canvas.DrawText("Movement: WASD; Turn: QE; Pitch: Mouse wheel.", 10, 30)
	
	End
	
End


' --- UTILS ----------------------


Enum Dir
	None = 0
	North
	East
	South
	West
	
	Length
End


' --- KEY BINDER ------------------


Enum Command
	ExitGame = 0
	MoveForward
	MoveBack
	StrafeLeft
	StrafeRight
	TurnLeft
	TurnRight
	Generate
End

Class KeyBinder Extends Map<Command, Key>

	Public
	
		Method New()
			Super.New()
			InitWASD()
		End

		Method InitWASD:Void()
		
			Add(Command.ExitGame, Key.Escape)
			Add(Command.MoveForward, Key.W | Key.Raw)
			Add(Command.MoveBack, Key.S | Key.Raw)
			Add(Command.StrafeLeft, Key.A | Key.Raw)
			Add(Command.StrafeRight, Key.D | Key.Raw)

			Add(Command.TurnLeft, Key.Q | Key.Raw)
			Add(Command.TurnRight, Key.E | Key.Raw)

			Add(Command.Generate, Key.Space | Key.Raw)

		End

End


' --- WORLD 3D ------------------


Class World3d

	'In this example all 3D objects (except camera and lights) are stored in this class.
	'Objects are organized into a grid to assist with collision testing and visibility.

	Field _cells:Cell3d[,]
	Field _cols:Int, _rows:Int

	Method New(cols:Int, rows:Int, scene:Scene)
	
		_cols = cols
		_rows = rows
		If _cols < 8 Then _cols = 8
		If _rows < 8 Then _rows = 8
		
		Local arr2d := New Barrier[_cols, _rows]
		GenerateMaze(arr2d)
		
		_cells = New Cell3d[_cols, _rows]

		For Local c := 0 Until _cols
			For Local r := 0 Until _rows
				_cells[c, r] = New Cell3d(c, r, arr2d[c, r])
				'Need to explicitly hide models because they are shown by default when created.
				_cells[c, r].Hide()
			Next
		Next
	
	End

	Property Cols:Int()
		Return _cols
	End
	
	Property Rows:Int()
		Return _rows
	End

	Property Cells:Cell3d[,]()
		Return _cells
	End

End


'----


Class Cell3d

	Public

		'Could probably set this to anything "realistic".
		Global CellSize:Vec3f = New Vec3f(6.0, 6.0, 6.0)

		Method New(col:Int, row:Int, barrier:Barrier)
		
			_col = col
			_row = row
			_barrier = barrier
			
			_centres = New Vec3f[Dir.Length]
			
			CalcCentres()
	
			CreateModels()
	
		End
	
		Property Blocked:Bool()
			Return _blocked
		Setter (value:Bool)
			_blocked = value
		End
		
		Method CalcCentres:Void()
		
			'These "centres" are used by the camera, depending on its facing direction.
			
			Local cx := (Float(_row) * CellSize.X) + (CellSize.X * 0.5)
			Local cy := (Cell3d.CellSize.Y * 0.66)
			Local cz := (Float(_col) * CellSize.Z) + (CellSize.Z * 0.5)
				
			SetCentre(Dir.None, cx, cy, cz)
			SetCentre(Dir.West, cx + (CellSize.X * 0.25), cy, cz)
			SetCentre(Dir.North, cx, cy, cz - (CellSize.Z * 0.25))
			SetCentre(Dir.East, cx - (CellSize.X * 0.25), cy, cz)
			SetCentre(Dir.South, cx, cy, cz + (CellSize.Z * 0.25))
		End
		
		Method SetCentre:Void(dir:Dir, x:Float, y:Float, z:Float)
			If (dir < 0) Or (dir >= _centres.Length) Then Return
			_centres[dir] = New Vec3f(x, y, z)
		End
	
		Method GetCentre:Vec3f(dir:Dir)
			If (dir < Dir.None) Or (dir >= _centres.Length) Then Return New Vec3f(-1, -1, -1)
			Return _centres[dir]
		End
	
		Method CreateModels:Void()
						
			'Using simple colored boxes for the floors, ceilings and walls.			
						
			Select _barrier

				Case Barrier.None
				
					_blocked = False
					
					_block = Null
					
					_floor = New Model(Mesh.CreateBox(New Boxf(0.0, 0.0, 0.0, CellSize.X, 0.2, CellSize.Z)), New PbrMaterial(New Color(1.0, Rnd(), Rnd()), 0.5, 0.5))		
					_floor.Position = New Vec3f(_row * CellSize.X, -0.20, _col * CellSize.Z)
					
					_ceil = New Model(Mesh.CreateBox(New Boxf(0.0, 0.0, 0.0, CellSize.X, 0.2, CellSize.Z)), New PbrMaterial(New Color(Rnd(), 1.0, Rnd()), 0.5, 0.5))
					_ceil.Position = New Vec3f(_row * CellSize.X, CellSize.Y, _col * CellSize.Z)
			
				Default

					_floor = Null
					_ceil = Null
				
					_blocked = True
					
					_block = New Model(Mesh.CreateBox(New Boxf(0.0, 0.0, 0.0, CellSize.X, CellSize.Y, CellSize.Z)), New PbrMaterial(New Color(Rnd(), Rnd(), 1.0), 0.5, 0.5))
					_block.Position = New Vec3f(_row * CellSize.X, 0.0, _col * CellSize.Z)
				
			End
				
		End

		Method Show:Void()
			'Show everything in the cell.
			If _block Then _block.Visible = True
			If _floor Then _floor.Visible = True
			If _ceil Then _ceil.Visible = True
		End	
		
		Method Hide:Void()
			'Hide everything in the cell.
			If _block Then _block.Visible = False
			If _floor Then _floor.Visible = False
			If _ceil Then _ceil.Visible = False
		End

	Private
	
		Field _block:Model
		Field _floor:Model
		Field _ceil:Model
			
		Field _blocked:Bool
		Field _centres:Vec3f[]
		Field _col:Int, _row:Int
		Field _barrier:Barrier
		
End


' --- RETRO STYLE DUNGEON CAMERA ------------------

'Grid movement ala Dungeon Master, Eye of the Beholder, et al.

Class RetroCam

	Public

		Method New(scene:Scene)
			
			_scene = scene
				
			_camera = New Camera()
			_camera.Near = 0.01
			_camera.Far = 100.0
			
			_camPath = New Vec3f[16]
			_camPathIdx = -1
			_camMoving = False
		
			_camTurnLeft = New Float[_camPath.Length]
			_camTurnRight = New Float[_camPath.Length]
			For Local i:Int = 0 Until _camPath.Length
				_camTurnLeft[i] = 90.0 / _camPath.Length
				_camTurnRight[i] = -_camTurnLeft[i]
			Next
		
			_camTurnIdx = -1
			_camTurning = False
					
			_viewRange = 5
			_visibleCells = New Stack<Cell3d>
			
			_pitchClamp = New Vec2f(-70.0, 70)
			
			FlipPitch = True

		End	

		Property Camera:Camera()
			Return _camera
		End

		Property FlipPitch:Bool()
			Return _flipPitch
		Setter (value:Bool)
			_flipPitch = value
		End

		Property Moving:Bool()
			Return _camMoving
		End
		
		Property Turning:Bool()
			Return _camTurning
		End

		Method SetCells3d:Void(cells3d:Cell3d[,], col:Int, row:Int, facingDir:Dir)
			If Not cells3d Then Return
			_cells3d = cells3d
			SetCoord(col, row, facingDir)
		End
		
		Method SetCoord:Void(col:Int, row:Int, facingDir:Dir)
			_facingDir = facingDir
			_cameraCol = col
			_cameraRow = row
			_camera.Position = _cells3d[_cameraCol, _cameraRow].GetCentre(_facingDir)
			ResetYaw()
			DoCameraMove(0, 0)
		End

		Method Update:Void()
		
			'Perform camera turning operation
			If _camTurning
				_camera.RotateY(_camTurn[_camTurnIdx])
				
				_camTurnIdx += 1
				If _camTurnIdx >= _camTurn.Length 
					_camTurning = False
				Endif
			Endif
	
			'Perform camera moving operation
			If _camMoving
				_camera.Position = _camPath[_camPathIdx]
				_camPathIdx += 1
				
				If _camPathIdx >= _camPath.Length 
					_camMoving = False
					_camera.Position = _cells3d[_cameraCol, _cameraRow].GetCentre(_facingDir)
					CalcVisibleCells()
				Endif
			Endif
		
		End

		Method StrafeLeft:Void()
			Select _facingDir
				Case Dir.North
					DoCameraMove(0, -1)
				Case Dir.East
					DoCameraMove(1, 0)
				Case Dir.South
					DoCameraMove(0, 1)
				Case Dir.West
					DoCameraMove(-1, 0)
			End
		End

		Method StrafeRight:Void()
			Select _facingDir
				Case Dir.North
					DoCameraMove(0, 1)
				Case Dir.East
					DoCameraMove(-1, 0)
				Case Dir.South
					DoCameraMove(0, -1)
				Case Dir.West
					DoCameraMove(1, 0)
			End
		End
		
		Method MoveBack:Void()
			Select _facingDir
				Case Dir.North
					DoCameraMove(-1, 0)
				Case Dir.East
					DoCameraMove(0, -1)
				Case Dir.South
					DoCameraMove(1, 0)
				Case Dir.West
					DoCameraMove(0, 1)
			End
		End
		
		Method MoveForward:Void()
			Select _facingDir
				Case Dir.North
					DoCameraMove(1, 0)
				Case Dir.East
					DoCameraMove(0, 1)
				Case Dir.South
					DoCameraMove(-1, 0)
				Case Dir.West
					DoCameraMove(0, -1)
			End
		End

		Method ResetPitch:Void()
		
			Local camrot := _camera.Rotation
			_camera.Rotation = New Vec3f(0.0, camrot.Y, camrot.Z)
		
		End
		
		Method ResetYaw:Void()
		
			Local camrot := _camera.Rotation	
			Local yaw:Float
		
			Select _facingDir
				Case Dir.North
					yaw = 0.0
				Case Dir.East
					yaw = 90.0
				Case Dir.South
					yaw = 180.0
				Case Dir.West
					yaw = 270.0
			End
		
			_camera.Rotation = New Vec3f(camrot.X, yaw, camrot.Z)
		
		End
		
		Method DoPitch:Void(amount:Float)
			
			Local camrot := _camera.Rotation
			Local newRotX:Float = _flipPitch ? camrot.X + amount Else camrot.X - amount

			newRotX = Clamp<Float>(newRotX, _pitchClamp.X, _pitchClamp.Y)
			_camera.Rotation = New Vec3f(newRotX, camrot.Y, camrot.Z)

		End
		
		Method DoCameraMove:Void(cOffset:Int, rOffset:Int)
		
			Local newCol := _cameraCol + cOffset
			Local newRow := _cameraRow + rOffset
		
			If newCol < 0 Or newRow < 0 Or newCol >= _cells3d.GetSize(0) Or newRow >= _cells3d.GetSize(1) Then Return
		
			If Not(_cells3d[newCol, newRow].Blocked)
		
				'If the cell is not blocked then move into it.
				'A linear path is calculated for a 'scrolling' effect.
			
				_cameraCol = newCol
				_cameraRow = newRow
			
				Local camX := _camera.X
				Local camZ := _camera.Z
						
				Local targ := _cells3d[newCol, newRow].GetCentre(_facingDir)
			
				Local diffX := camX - targ.X
				Local diffZ := camZ - targ.Z
									
				For Local pathIdx := 0 Until _camPath.Length
					_camPath[pathIdx].x = camX - (pathIdx * (diffX / _camPath.Length))
					_camPath[pathIdx].z = camZ - (pathIdx * (diffZ / _camPath.Length))	
					_camPath[pathIdx].y = (Cell3d.CellSize.Y * 0.66)
				Next
						
				_camPathIdx = 0
				_camMoving = True
			Endif

		End

		'Turn camera, either left or right.
		Method DoCameraTurn:Void(left:Bool)
			
			ResetPitch()
				
			If left
					
				_facingDir = Cast<Dir>(Cast<Int>(_facingDir) - 1)
				If _facingDir <= Dir.None Then _facingDir = Dir.West
				
				_camTurn = _camTurnLeft
					
			Else
			
				_facingDir = Cast<Dir>(Cast<Int>(_facingDir) + 1)
				If _facingDir >= Dir.Length Then _facingDir = Dir.North
	
				_camTurn = _camTurnRight
	
			Endif
	
			'need to 'tweak' the camera's x, z position based on the new facing direction.
			DoCameraMove(0, 0)
		
			_camTurnIdx = 0
			_camTurning = True
	
		End

		'Hide entities outside the camera's view range. This improves performance significantly.
		Method CalcVisibleCells:Void()

			If Not _cells3d Then Return

			Local cols := _cells3d.GetSize(0)
			Local rows := _cells3d.GetSize(1)
	
			For Local cell := Eachin _visibleCells
				cell.Hide()
			Next
			_visibleCells.Clear()
					
			For Local c := _cameraCol - _viewRange To _cameraCol + _viewRange
				For Local r := _cameraRow - _viewRange To _cameraRow + _viewRange
					If c >= 0 And c < cols And r >= 0 And r < rows
						_visibleCells.Push(_cells3d[c, r])
						_cells3d[c, r].Show()
					Endif
				Next
			Next 	

		End
	
	Private

		Field _camera:Camera
		Field _scene:Scene

		Field _facingDir:Dir				'Camera's current facing direction. This is critical for 
											'positioning, turning and movement calculations.

		Field _cameraCol:Int
		Field _cameraRow:Int

		Field _camPath:Vec3f[]				'Current camera movement path.
		Field _camPathIdx:Int				'Index position of current camera movement path.
		Field _camMoving:Bool				'Camera is moving?
		
		Field _camTurn:Float[]				'Current camera turning path. 
		Field _camTurnLeft:Float[]			'Pre-calculated left camera turning path.
		Field _camTurnRight:Float[]			'Pre-calculated right camera turning path.
		Field _camTurnIdx:Int				'Index position of current camera turning path.
		Field _camTurning:Bool				'Camera is turning?

		Field _cells3d:Cell3d[,]			'Reference to a grid of 3d cells.

		Field _viewRange:Int				'number of cells
		Field _visibleCells:Stack<Cell3d>	'visible cells (calculated upon movement command).

		Field _pitchClamp:Vec2f				'Restrict the camera pitch minimum and maxumum.
		Field _flipPitch:Bool				

End


' --- MAZE GENERATOR ------------------


Enum Barrier
	None = 0
	Block
End

Struct Cell

	Public
	
		Field North:Bool = True
		Field East:Bool = True
		Field South:Bool = True
		Field West:Bool = True
			
End

Function GenerateMaze:Void(arr2d:Barrier[,])
	
	'Generate a perfect maze (every coordinate is reachable by every other coordinate) within a 2D array.
	
	If Not arr2d Then Return
	
	Local cols:Int = arr2d.GetSize(0)
	Local rows:Int = arr2d.GetSize(1)

	Local cellCols:Int
	If (cols Mod 2 <> 0) Then cellCols = Floor(cols / 2) Else cellCols = Floor((cols - 1) / 2)
	
	Local cellRows:Int
	If (rows Mod 2 <> 0) Then cellRows = Floor(rows / 2) Else cellRows = Floor((rows - 1) / 2)
	
	Local totalCells:Int = cellRows * cellCols
	
	Local cellMaze:= New Cell[cellCols, cellRows]
	Local track := New Vec2i[totalCells]
	Local tri:Int = 0
	Local dir:= New Vec2i[4], nextCoord := New Vec2i[4]
	Local curCoord:Vec2i
	Local visited:int, i:Int, mazei:Int, nbi:Int, r:Int, c:Int	
		
    For r = 0 Until cellRows 
        For c = 0 Until cellCols
        	i = (r * cellCols) + c
        	cellMaze[c, r] = New Cell()
        	track[i] = New Vec2i
        Next
    Next

	For i = 0 Until dir.Length
		dir[i] = New Vec2i
		nextCoord[i] = New Vec2i
	Next
	
    dir[0].Y = -1	'north
    dir[1].X = 1	'east
    dir[2].Y = 1	'south
    dir[3].X = -1	'west
	
	curCoord.Y = Floor(Rnd(0, cellRows))
	curCoord.X = Floor(Rnd(0, cellCols))
	
	visited = 1
	
	While (visited < totalCells)
        nbi = 0
        For i = 0 Until dir.Length
            r = curCoord.Y + dir[i].Y
            c = curCoord.X + dir[i].X
            If (r >= 0) And (r < cellRows) And (c >= 0) And (c < cellCols)
                If (cellMaze[c, r].North) And (cellMaze[c, r].East) And (cellMaze[c, r].South) And (cellMaze[c, r].West)
                    nextCoord[nbi].Y = r
                    nextCoord[nbi].X = c
                    nbi += 1
                Endif
            Endif
        Next
        
        if (nbi >= 1) 
            i = Floor(Rnd(0, nbi))
            If (nextCoord[i].Y - curCoord.Y) = 0 Then    
                r = nextCoord[i].Y
                If nextCoord[i].X > curCoord.X Then      
                    c = curCoord.X
                    cellMaze[c, r].East = False
                    c = nextCoord[i].X
                    cellMaze[c, r].West = False
                else                                
                    c = curCoord.X
                    cellMaze[c, r].West = False
                    c = nextCoord[i].X
                    cellMaze[c, r].East = False
                endif
            else                                    
                c = nextCoord[i].X
                If nextCoord[i].Y > curCoord.Y Then      
                    r = curCoord.Y
                    cellMaze[c, r].South = False
                    r = nextCoord[i].Y
                    cellMaze[c, r].North = False
                Else                                
                    r = curCoord.Y
                    cellMaze[c, r].North = False
                    r = nextCoord[i].Y
                    cellMaze[c, r].South = false
                endif
            Endif

            tri += 1
            track[tri].Y = curCoord.Y
            track[tri].X = curCoord.X

            curCoord.Y = nextCoord[i].Y
            curCoord.X = nextCoord[i].X
           
            visited += 1
        Else
            curCoord.Y = track[tri].Y
            curCoord.X = track[tri].X
            tri -= 1
        Endif 
    Wend

	'--- Remap maze cells to 2d array.
	
	For Local r := 0 Until rows
		For Local c := 0 Until cols
			arr2d[c, r] = Barrier.Block
		Next
	Next
	
	Local mazer:Int, mazec:Int

	For Local r := 0 Until cellRows
		mazer = (r * 2) + 1	
		For Local c := 0 Until cellCols
			mazec = (c * 2) + 1
			arr2d[mazec, mazer] = Barrier.None
			
			If (Not cellMaze[c, r].West) Then arr2d[mazec - 1, mazer] = Barrier.None
			If (Not cellMaze[c, r].North) Then arr2d[mazec, mazer - 1] = Barrier.None	
		Next
	Next

End

100

101

102

103

104

105

106

107

108

109

110

111

112

113

114

115

116

117

118

119

120

121

122

123

124

125

126

127

128

129

130

131

132

133

134

135

136

137

138

139

140

141

142

143

144

145

146

147

148

149

150

151

152

153

154

155

156

157

158

159

160

161

162

163

164

165

166

167

168

169

170

171

172

173

174

175

176

177

178

179

180

181

182

183

184

185

186

187

188

189

190

191

192

193

194

195

196

197

198

199

200

201

202

203

204

205

206

207

208

209

210

211

212

213

214

215

216

217

218

219

220

221

222

223

224

225

226

227

228

229

230

231

232

233

234

235

236

237

238

239

240

241

242

243

244

245

246

247

248

249

250

251

252

253

254

255

256

257

258

259

260

261

262

263

264

265

266

267

268

269

270

271

272

273

274

275

276

277

278

279

280

281

282

283

284

285

286

287

288

289

290

291

292

293

294

295

296

297

298

299

300

301

302

303

304

305

306

307

308

309

310

311

312

313

314

315

316

317

318

319

320

321

322

323

324

325

326

327

328

329

330

331

332

333

334

335

336

337

338

339

340

341

342

343

344

345

346

347

348

349

350

351

352

353

354

355

356

357

358

359

360

361

362

363

364

365

366

367

368

369

370

371

372

373

374

375

376

377

378

379

380

381

382

383

384

385

386

387

388

389

390

391

392

393

394

395

396

397

398

399

400

401

402

403

404

405

406

407

408

409

410

411

412

413

414

415

416

417

418

419

420

421

422

423

424

425

426

427

428

429

430

431

432

433

434

435

436

437

438

439

440

441

442

443

444

445

446

447

448

449

450

451

452

453

454

455

456

457

458

459

460

461

462

463

464

465

466

467

468

469

470

471

472

473

474

475

476

477

478

479

480

481

482

483

484

485

486

487

488

489

490

491

492

493

494

495

496

497

498

499

500

501

502

503

504

505

506

507

508

509

510

511

512

513

514

515

516

517

518

519

520

521

522

523

524

525

526

527

528

529

530

531

532

533

534

535

536

537

538

539

540

541

542

543

544

545

546

547

548

549

550

551

552

553

554

555

556

557

558

559

560

561

562

563

564

565

566

567

568

569

570

571

572

573

574

575

576

577

578

579

580

581

582

583

584

585

586

587

588

589

590

591

592

593

594

595

596

597

598

599

600

601

602

603

604

605

606

607

608

609

610

611

612

613

614

615

616

617

618

619

620

621

622

623

624

625

626

627

628

629

630

631

632

633

634

635

636

637

638

639

640

641

642

643

644

645

646

647

648

649

650

651

652

653

654

655

656

657

658

659

660

661

662

663

664

665

666

667

668

669

670

671

672

673

674

675

676

677

678

679

680

681

682

683

684

685

686

687

688

689

690

691

692

693

694

695

696

697

698

699

700

701

702

703

704

705

706

707

708

709

710

711

712

713

714

715

716

717

718

719

720

721

722

723

724

725

726

727

728

729

730

731

732

733

734

735

736

737

738

739

740

741

742

743

744

745

746

747

748

749

750

751

752

753

754

755

756

757

758

759

760

761

762

763

764

765

766

767

768

769

770

771

772

773

774

775

776

777

778

779

780

781

782

783

784

785

786

787

788

789

790

791

792

793

794

795

796

797

798

799

800

801

802

803

804

805

806

807

808

809

810

811

812

813

814

815

816

817

818

819

820

821

822

823

824

825

826

827

828

829

830

831

832

833

834

835

836

837

838

839

840

841

842

843

844

845

846

847

848

849

850

851

852

853

854

855

856

857

858

859

860

861

862

863

864

865

866

867

868

869

#rem

3d grid-based movement within a procedurally generated maze.

#end

#Import "<std>"

#Import "<mojo>"

#Import "<mojo3d>"

Using libc..

Using std..

Using mojo..

Using mojo3d..

Function Main()

New AppInstance

New MyWindow("Retro Dungeon Test", 1024, 768, WindowFlags.Fullscreen)

App.Run()

End

' --- MOJO WINDOW ----------------------

Class MyWindow Extends Window

Field _scene:Scene

Field _light:Light

Field _retroCam:RetroCam

Field _keyBinder:KeyBinder

Field _world3d:World3d

Method New( title:String="Simple mojo app",width:Int=1024,height:Int=768,flags:WindowFlags = WindowFlags.Resizable | WindowFlags.HighDPI)

Super.New( title,width,height,flags )

_scene = Scene.GetCurrent()

_scene.ClearColor = Color.Black

_scene.AmbientLight = Color.DarkGrey

'The black fog provides atmosphere and hides the 'pop-in' effect of visible/hidden cells.

_scene.FogColor = Color.Black

_scene.FogNear = Cell3d.CellSize.X

_scene.FogFar = Cell3d.CellSize.X * 3

_keyBinder = New KeyBinder()

_retroCam = New RetroCam(_scene)

'The light is not yet properly functional.

_light=New Light(_retroCam.Camera)

_light.Color = Color.Orange

_light.Type = LightType.Directional

_light.Range = Cell3d.CellSize.X * 4.0

SeedRnd(Microsecs())

Generate()

End

Method Generate:Void()

Print "Generating maze. Please wait."

Local ms:=Millisecs()

'32 columns and 32 rows.

_world3d = New World3d(32, 32, _scene)

Print "Generation time (millisecs): " + String(Millisecs() - ms)

'3d cells, starting column and row, and a facing direction.

_retroCam.SetCells3d(_world3d.Cells, 1, 1, Dir.North)

End

Method OnUpdate:Void()

HandleKeys()

HandleMouse()

_retroCam.Update()

End

Method HandleMouse:Void()

If Mouse.Wheel.Y <> 0

'Look up and down.

_retroCam.DoPitch(Float(Mouse.Wheel.Y) * 10)

Endif

If Mouse.ButtonDown(MouseButton.Middle)

'Reset the pitch.

_retroCam.ResetPitch()

Elseif Mouse.ButtonDown(MouseButton.Left)

If Not _retroCam.Moving And Not _retroCam.Turning

'Left click on screen/window edges will move or turn depending on mouse location.

If Mouse.Location.X < (0.1 * Width)

If Mouse.Location.Y > Height - (0.2 * Height)

_retroCam.StrafeLeft()

Else

_retroCam.DoCameraTurn(True)

EndIf

Elseif Mouse.Location.X > Width - (0.1 * Width)

If Mouse.Location.Y > Height - (0.2 * Height)

_retroCam.StrafeRight()

Else

_retroCam.DoCameraTurn(False)

EndIf

Elseif Mouse.Location.Y < (0.1 * Height)

_retroCam.MoveForward()

Elseif Mouse.Location.Y > Height - (0.1 * Height)

_retroCam.MoveBack()

Endif

End

Method HandleKeys:Void()

If Not _keyBinder Then Return

'Only process input if camera not moving or turning.

If (Not _retroCam.Moving) And (Not _retroCam.Turning)

If Keyboard.KeyDown(_keyBinder.Get(Command.ExitGame))

App.Terminate()

Endif

If Keyboard.KeyDown(_keyBinder.Get(Command.TurnLeft))

_retroCam.DoCameraTurn(True)

Return

Elseif Keyboard.KeyDown(_keyBinder.Get(Command.TurnRight))

_retroCam.DoCameraTurn(False)

Return

Endif

If Keyboard.KeyDown(_keyBinder.Get(Command.MoveForward))

_retroCam.MoveForward()

Return

Endif

If Keyboard.KeyDown(_keyBinder.Get(Command.MoveBack))

_retroCam.MoveBack()

Return

Endif

If Keyboard.KeyDown(_keyBinder.Get(Command.StrafeRight))

_retroCam.StrafeRight()

Return

Endif

If Keyboard.KeyDown(_keyBinder.Get(Command.StrafeLeft))

_retroCam.StrafeLeft()

Return

Endif

If Keyboard.KeyDown(_keyBinder.Get(Command.Generate))

Generate()

Endif

End

Method OnRender:Void(canvas:Canvas) Override

RequestRender()

'******

OnUpdate()

'******

_scene.Update()

_retroCam.Camera.Render(canvas)

'_scene.Render(canvas, _retroCam.Camera)

canvas.DrawText("FPS: "+ App.FPS, 10, 10)

canvas.DrawText("Movement: WASD; Turn: QE; Pitch: Mouse wheel.", 10, 30)

End

' --- UTILS ----------------------

Enum Dir

None = 0

North

East

South

West

Length

End

' --- KEY BINDER ------------------

Enum Command

ExitGame = 0

MoveForward

MoveBack

StrafeLeft

StrafeRight

TurnLeft

TurnRight

Generate

End

Class KeyBinder Extends Map<Command, Key>

Public

Method New()

Super.New()

InitWASD()

End

Method InitWASD:Void()

Add(Command.ExitGame, Key.Escape)

Add(Command.MoveForward, Key.W | Key.Raw)

Add(Command.MoveBack, Key.S | Key.Raw)

Add(Command.StrafeLeft, Key.A | Key.Raw)

Add(Command.StrafeRight, Key.D | Key.Raw)

Add(Command.TurnLeft, Key.Q | Key.Raw)

Add(Command.TurnRight, Key.E | Key.Raw)

Add(Command.Generate, Key.Space | Key.Raw)

End

' --- WORLD 3D ------------------

Class World3d

'In this example all 3D objects (except camera and lights) are stored in this class.

'Objects are organized into a grid to assist with collision testing and visibility.

Field _cells:Cell3d[,]

Field _cols:Int, _rows:Int

Method New(cols:Int, rows:Int, scene:Scene)

_cols = cols

_rows = rows

If _cols < 8 Then _cols = 8

If _rows < 8 Then _rows = 8

Local arr2d := New Barrier[_cols, _rows]

GenerateMaze(arr2d)

_cells = New Cell3d[_cols, _rows]

For Local c := 0 Until _cols

For Local r := 0 Until _rows

_cells[c, r] = New Cell3d(c, r, arr2d[c, r])

'Need to explicitly hide models because they are shown by default when created.

_cells[c, r].Hide()

End

Property Cols:Int()

Return _cols

End

Property Rows:Int()

Return _rows

End

Property Cells:Cell3d[,]()

Return _cells

End

'----

Class Cell3d

Public

'Could probably set this to anything "realistic".

Global CellSize:Vec3f = New Vec3f(6.0, 6.0, 6.0)

Method New(col:Int, row:Int, barrier:Barrier)

_col = col

_row = row

_barrier = barrier

_centres = New Vec3f[Dir.Length]

CalcCentres()

CreateModels()

End

Property Blocked:Bool()

Return _blocked

Setter (value:Bool)

_blocked = value

End

Method CalcCentres:Void()

'These "centres" are used by the camera, depending on its facing direction.

Local cx := (Float(_row) * CellSize.X) + (CellSize.X * 0.5)

Local cy := (Cell3d.CellSize.Y * 0.66)

Local cz := (Float(_col) * CellSize.Z) + (CellSize.Z * 0.5)

SetCentre(Dir.None, cx, cy, cz)

SetCentre(Dir.West, cx + (CellSize.X * 0.25), cy, cz)

SetCentre(Dir.North, cx, cy, cz - (CellSize.Z * 0.25))

SetCentre(Dir.East, cx - (CellSize.X * 0.25), cy, cz)

SetCentre(Dir.South, cx, cy, cz + (CellSize.Z * 0.25))

End

Method SetCentre:Void(dir:Dir, x:Float, y:Float, z:Float)

If (dir < 0) Or (dir >= _centres.Length) Then Return

_centres[dir] = New Vec3f(x, y, z)

End

Method GetCentre:Vec3f(dir:Dir)

If (dir < Dir.None) Or (dir >= _centres.Length) Then Return New Vec3f(-1, -1, -1)

Return _centres[dir]

End

Method CreateModels:Void()

'Using simple colored boxes for the floors, ceilings and walls.

Select _barrier

Case Barrier.None

_blocked = False

_block = Null

_floor = New Model(Mesh.CreateBox(New Boxf(0.0, 0.0, 0.0, CellSize.X, 0.2, CellSize.Z)), New PbrMaterial(New Color(1.0, Rnd(), Rnd()), 0.5, 0.5))

_floor.Position = New Vec3f(_row * CellSize.X, -0.20, _col * CellSize.Z)

_ceil = New Model(Mesh.CreateBox(New Boxf(0.0, 0.0, 0.0, CellSize.X, 0.2, CellSize.Z)), New PbrMaterial(New Color(Rnd(), 1.0, Rnd()), 0.5, 0.5))

_ceil.Position = New Vec3f(_row * CellSize.X, CellSize.Y, _col * CellSize.Z)

Default

_floor = Null

_ceil = Null

_blocked = True

_block = New Model(Mesh.CreateBox(New Boxf(0.0, 0.0, 0.0, CellSize.X, CellSize.Y, CellSize.Z)), New PbrMaterial(New Color(Rnd(), Rnd(), 1.0), 0.5, 0.5))

_block.Position = New Vec3f(_row * CellSize.X, 0.0, _col * CellSize.Z)

End

Method Show:Void()

'Show everything in the cell.

If _block Then _block.Visible = True

If _floor Then _floor.Visible = True

If _ceil Then _ceil.Visible = True

End

Method Hide:Void()

'Hide everything in the cell.

If _block Then _block.Visible = False

If _floor Then _floor.Visible = False

If _ceil Then _ceil.Visible = False

End

Private

Field _block:Model

Field _floor:Model

Field _ceil:Model

Field _blocked:Bool

Field _centres:Vec3f[]

Field _col:Int, _row:Int

Field _barrier:Barrier

End

' --- RETRO STYLE DUNGEON CAMERA ------------------

'Grid movement ala Dungeon Master, Eye of the Beholder, et al.

Class RetroCam

Public

Method New(scene:Scene)

_scene = scene

_camera = New Camera()

_camera.Near = 0.01

_camera.Far = 100.0

_camPath = New Vec3f[16]

_camPathIdx = -1

_camMoving = False

_camTurnLeft = New Float[_camPath.Length]

_camTurnRight = New Float[_camPath.Length]

For Local i:Int = 0 Until _camPath.Length

_camTurnLeft[i] = 90.0 / _camPath.Length

_camTurnRight[i] = -_camTurnLeft[i]

_camTurnIdx = -1

_camTurning = False

_viewRange = 5

_visibleCells = New Stack<Cell3d>

_pitchClamp = New Vec2f(-70.0, 70)

FlipPitch = True

End

Property Camera:Camera()

Return _camera

End

Property FlipPitch:Bool()

Return _flipPitch

Setter (value:Bool)

_flipPitch = value

End

Property Moving:Bool()

Return _camMoving

End

Property Turning:Bool()

Return _camTurning

End

Method SetCells3d:Void(cells3d:Cell3d[,], col:Int, row:Int, facingDir:Dir)

If Not cells3d Then Return

_cells3d = cells3d

SetCoord(col, row, facingDir)

End

Method SetCoord:Void(col:Int, row:Int, facingDir:Dir)

_facingDir = facingDir

_cameraCol = col

_cameraRow = row

_camera.Position = _cells3d[_cameraCol, _cameraRow].GetCentre(_facingDir)

ResetYaw()

DoCameraMove(0, 0)

End

Method Update:Void()

'Perform camera turning operation

If _camTurning

_camera.RotateY(_camTurn[_camTurnIdx])

_camTurnIdx += 1

If _camTurnIdx >= _camTurn.Length

_camTurning = False

Endif

'Perform camera moving operation

If _camMoving

_camera.Position = _camPath[_camPathIdx]

_camPathIdx += 1

If _camPathIdx >= _camPath.Length

_camMoving = False

_camera.Position = _cells3d[_cameraCol, _cameraRow].GetCentre(_facingDir)

CalcVisibleCells()

Endif

End

Method StrafeLeft:Void()

Select _facingDir

Case Dir.North

DoCameraMove(0, -1)

Case Dir.East

DoCameraMove(1, 0)

Case Dir.South

DoCameraMove(0, 1)

Case Dir.West

DoCameraMove(-1, 0)

End

Method StrafeRight:Void()

Select _facingDir

Case Dir.North

DoCameraMove(0, 1)

Case Dir.East

DoCameraMove(-1, 0)

Case Dir.South

DoCameraMove(0, -1)

Case Dir.West

DoCameraMove(1, 0)

End

Method MoveBack:Void()

Select _facingDir

Case Dir.North

DoCameraMove(-1, 0)

Case Dir.East

DoCameraMove(0, -1)

Case Dir.South

DoCameraMove(1, 0)

Case Dir.West

DoCameraMove(0, 1)

End

Method MoveForward:Void()

Select _facingDir

Case Dir.North

DoCameraMove(1, 0)

Case Dir.East

DoCameraMove(0, 1)

Case Dir.South

DoCameraMove(-1, 0)

Case Dir.West

DoCameraMove(0, -1)

End

Method ResetPitch:Void()

Local camrot := _camera.Rotation

_camera.Rotation = New Vec3f(0.0, camrot.Y, camrot.Z)

End

Method ResetYaw:Void()

Local camrot := _camera.Rotation

Local yaw:Float

Select _facingDir

Case Dir.North

yaw = 0.0

Case Dir.East

yaw = 90.0

Case Dir.South

yaw = 180.0

Case Dir.West

yaw = 270.0

End

_camera.Rotation = New Vec3f(camrot.X, yaw, camrot.Z)

End

Method DoPitch:Void(amount:Float)

Local camrot := _camera.Rotation

Local newRotX:Float = _flipPitch ? camrot.X + amount Else camrot.X - amount

newRotX = Clamp<Float>(newRotX, _pitchClamp.X, _pitchClamp.Y)

_camera.Rotation = New Vec3f(newRotX, camrot.Y, camrot.Z)

End

Method DoCameraMove:Void(cOffset:Int, rOffset:Int)

Local newCol := _cameraCol + cOffset

Local newRow := _cameraRow + rOffset

If newCol < 0 Or newRow < 0 Or newCol >= _cells3d.GetSize(0) Or newRow >= _cells3d.GetSize(1) Then Return

If Not(_cells3d[newCol, newRow].Blocked)

'If the cell is not blocked then move into it.

'A linear path is calculated for a 'scrolling' effect.

_cameraCol = newCol

_cameraRow = newRow

Local camX := _camera.X

Local camZ := _camera.Z

Local targ := _cells3d[newCol, newRow].GetCentre(_facingDir)

Local diffX := camX - targ.X

Local diffZ := camZ - targ.Z

For Local pathIdx := 0 Until _camPath.Length

_camPath[pathIdx].x = camX - (pathIdx * (diffX / _camPath.Length))

_camPath[pathIdx].z = camZ - (pathIdx * (diffZ / _camPath.Length))

_camPath[pathIdx].y = (Cell3d.CellSize.Y * 0.66)

_camPathIdx = 0

_camMoving = True

Endif

End

'Turn camera, either left or right.

Method DoCameraTurn:Void(left:Bool)

ResetPitch()

If left

_facingDir = Cast<Dir>(Cast<Int>(_facingDir) - 1)

If _facingDir <= Dir.None Then _facingDir = Dir.West

_camTurn = _camTurnLeft

Else

_facingDir = Cast<Dir>(Cast<Int>(_facingDir) + 1)

If _facingDir >= Dir.Length Then _facingDir = Dir.North

_camTurn = _camTurnRight

Endif

'need to 'tweak' the camera's x, z position based on the new facing direction.

DoCameraMove(0, 0)

_camTurnIdx = 0

_camTurning = True

End

'Hide entities outside the camera's view range. This improves performance significantly.

Method CalcVisibleCells:Void()

If Not _cells3d Then Return

Local cols := _cells3d.GetSize(0)

Local rows := _cells3d.GetSize(1)

For Local cell := Eachin _visibleCells

cell.Hide()

_visibleCells.Clear()

For Local c := _cameraCol - _viewRange To _cameraCol + _viewRange

For Local r := _cameraRow - _viewRange To _cameraRow + _viewRange

If c >= 0 And c < cols And r >= 0 And r < rows

_visibleCells.Push(_cells3d[c, r])

_cells3d[c, r].Show()

Endif

End

Private

Field _camera:Camera

Field _scene:Scene

Field _facingDir:Dir 'Camera's current facing direction. This is critical for

'positioning, turning and movement calculations.

Field _cameraCol:Int

Field _cameraRow:Int

Field _camPath:Vec3f[] 'Current camera movement path.

Field _camPathIdx:Int 'Index position of current camera movement path.

Field _camMoving:Bool 'Camera is moving?

Field _camTurn:Float[] 'Current camera turning path.

Field _camTurnLeft:Float[] 'Pre-calculated left camera turning path.

Field _camTurnRight:Float[] 'Pre-calculated right camera turning path.

Field _camTurnIdx:Int 'Index position of current camera turning path.

Field _camTurning:Bool 'Camera is turning?

Field _cells3d:Cell3d[,] 'Reference to a grid of 3d cells.

Field _viewRange:Int 'number of cells

Field _visibleCells:Stack<Cell3d> 'visible cells (calculated upon movement command).

Field _pitchClamp:Vec2f 'Restrict the camera pitch minimum and maxumum.

Field _flipPitch:Bool

End

' --- MAZE GENERATOR ------------------

Enum Barrier

None = 0

Block

End

Struct Cell

Public

Field North:Bool = True

Field East:Bool = True

Field South:Bool = True

Field West:Bool = True

End

Function GenerateMaze:Void(arr2d:Barrier[,])

'Generate a perfect maze (every coordinate is reachable by every other coordinate) within a 2D array.

If Not arr2d Then Return

Local cols:Int = arr2d.GetSize(0)

Local rows:Int = arr2d.GetSize(1)

Local cellCols:Int

If (cols Mod 2 <> 0) Then cellCols = Floor(cols / 2) Else cellCols = Floor((cols - 1) / 2)

Local cellRows:Int

If (rows Mod 2 <> 0) Then cellRows = Floor(rows / 2) Else cellRows = Floor((rows - 1) / 2)

Local totalCells:Int = cellRows * cellCols

Local cellMaze:= New Cell[cellCols, cellRows]

Local track := New Vec2i[totalCells]

Local tri:Int = 0

Local dir:= New Vec2i[4], nextCoord := New Vec2i[4]

Local curCoord:Vec2i

Local visited:int, i:Int, mazei:Int, nbi:Int, r:Int, c:Int

For r = 0 Until cellRows

For c = 0 Until cellCols

i = (r * cellCols) + c

cellMaze[c, r] = New Cell()

track[i] = New Vec2i

For i = 0 Until dir.Length

dir[i] = New Vec2i

nextCoord[i] = New Vec2i

dir[0].Y = -1 'north

dir[1].X = 1 'east

dir[2].Y = 1 'south

dir[3].X = -1 'west

curCoord.Y = Floor(Rnd(0, cellRows))

curCoord.X = Floor(Rnd(0, cellCols))

visited = 1

While (visited < totalCells)

nbi = 0

For i = 0 Until dir.Length

r = curCoord.Y + dir[i].Y

c = curCoord.X + dir[i].X

If (r >= 0) And (r < cellRows) And (c >= 0) And (c < cellCols)

If (cellMaze[c, r].North) And (cellMaze[c, r].East) And (cellMaze[c, r].South) And (cellMaze[c, r].West)

nextCoord[nbi].Y = r

nextCoord[nbi].X = c

nbi += 1

Endif

if (nbi >= 1)

i = Floor(Rnd(0, nbi))

If (nextCoord[i].Y - curCoord.Y) = 0 Then

r = nextCoord[i].Y

If nextCoord[i].X > curCoord.X Then

c = curCoord.X

cellMaze[c, r].East = False

c = nextCoord[i].X

cellMaze[c, r].West = False

else

c = curCoord.X

cellMaze[c, r].West = False

c = nextCoord[i].X

cellMaze[c, r].East = False

endif

else

c = nextCoord[i].X

If nextCoord[i].Y > curCoord.Y Then

r = curCoord.Y

cellMaze[c, r].South = False

r = nextCoord[i].Y

cellMaze[c, r].North = False

Else

r = curCoord.Y

cellMaze[c, r].North = False

r = nextCoord[i].Y

cellMaze[c, r].South = false

endif

Endif

tri += 1

track[tri].Y = curCoord.Y

track[tri].X = curCoord.X

curCoord.Y = nextCoord[i].Y

curCoord.X = nextCoord[i].X

visited += 1

Else

curCoord.Y = track[tri].Y

curCoord.X = track[tri].X

tri -= 1

Endif

Wend

'--- Remap maze cells to 2d array.

For Local r := 0 Until rows

For Local c := 0 Until cols

arr2d[c, r] = Barrier.Block

Local mazer:Int, mazec:Int

For Local r := 0 Until cellRows

mazer = (r * 2) + 1

For Local c := 0 Until cellCols

mazec = (c * 2) + 1

arr2d[mazec, mazer] = Barrier.None

If (Not cellMaze[c, r].West) Then arr2d[mazec - 1, mazer] = Barrier.None

If (Not cellMaze[c, r].North) Then arr2d[mazec, mazer - 1] = Barrier.None

End

August 2, 2017 at 2:59 am #9662

Pakz

Participant

The Q and E buttons make the screen turn like crazy. Something wrong there on my system.

I also had a security message when I wanted to paste a error log using the code box. This was in the dev forum. I saw a fox image iirc.

August 2, 2017 at 3:11 am #9663

Mark Sibly

Keymaster

The Q and E buttons make the screen turn like crazy. Something wrong there on my system.

You’r probably still using radians version of mojo3d – angular units will change to degrees in next release (tomorrow probably).

Nice demo though, although I’m a teeny bit disappointed it’s not a ‘real’ 3d maze!

I get “*** Forbidden: Message seems to be spam. ***

Yeah I need to work out what’s up with cleantalk, the antispam provider.

August 2, 2017 at 3:47 am #9664

impixi

Participant

Yes, the demo is coded against the latest monkey 2 dev branch where mojo3d is now using degrees instead of radians…

@Mark
What do you mean by ‘real’ 3d maze? Multiple levels high, stacked like a tower? Or “free-form” movement?

August 2, 2017 at 3:59 am #9665

Mark Sibly

Keymaster

What do you mean by ‘real’ 3d maze?

A maze that goes from A to B where A and B are 3d points and corridors can go left/right/up/down!

August 2, 2017 at 5:26 am #9666

impixi

Participant

Ahhh, like a “hypermaze”:

http://www.astrolog.org/labyrnth/maze/hyper.gif
http://www.astrolog.org/labyrnth/hypermaz.htm

Indeed, that would be an absolute nightmare to navigate, though, even with a map.

January 28, 2018 at 8:59 am #13313

impixi

Participant

There has been some mojo3d architectural changes since I first posted this example so I fixed it to run with the current mojo3d module.

Also, how can I remove the old file attachment from my initial post?

January 28, 2018 at 9:50 am #13315

Mark Sibly

Keymaster

Also, how can I remove the old file attachment from my initial post?

Should be gone now?

Thanks for the update too!

Author

Posts

Viewing 8 posts - 1 through 8 (of 8 total)

You must be logged in to reply to this topic.

3D Grid-based movement

Archives

Recent Replies

What is this?