Class tlGameObject Virtual

Entities can be parented to other entities and maintain and update a list of children. These children can be relative to their parents therefore minimising the work needed to calculate where entities should be drawn to the screen. If a parent rotates, then it's children will rotate with it and likewise, if the parent moves then its children will move with it as well. Children don't have to be relative however, set realative to false using Relative to make the children move independantly, however they will still be updated by their parent

If you have an entity with children, and those children in turn have children, in order to update all of those entities only one call to the parent Update method is required to see all of the children updated too. This also applies to rendering the entities on screen - by calling Render on the parent entityall children entities will also be rendered. See the code below for an example

Entities draw to the screen using tlShape, a class that allows you to easily draw single or animated images. To set the image use Image and LoadShape. You can adjust the appearence of the entity such as colour and scale using commands such as Red, Green, Blue, Alpha, SetScale and Angle.

When entities are rendered they can be tweened so that their animation and movement on the screen is smoothed out using fixed rate timing. You pass the tween value when you call Render but it's only optional.

tlGameObject os component based, meaning it uses tlComponents to add functionality. tlComponent is an abstract class you can extend and override the update method to add whatever functionality you need to the object, be it a control system or movement. You can create as many components as you need for an object and they can be re-used as much as you need. See tlComponent for more info.

Namespace myapp


Using std..
Using mojo..
Using timelinefx..

Class MyWindow Extends Window

	Field GameObject:tlGameObject
	Field ChildObject:tlGameObject

	Method New( title:String="tlGameObject example",width:Int=640,height:Int=480,flags:WindowFlags=Null )

		Super.New( title,width,height,flags )

		'Create a couple of new game objects
		GameObject = New tlGameObject
		ChildObject = New tlGameObject

		'Assign images using LoadShape
		GameObject.Image = LoadShape("asset::smoke.png")
		ChildObject.Image = LoadShape("asset::smoke.png")

		'Position the child object. This will be relative to the parent object.
		ChildObject.SetPosition(0, 200)
		'Scale it down a bit
		ChildObject.SetScale(0.5)

		'Add the child object to the parent object
		GameObject.AddChild(ChildObject)
		'Set the parent position
		GameObject.SetPosition(width/2, height/2)
		'Update the gameobject to make sure everything is initialised in the correct positions
		GameObject.Update()
	End

	Method OnRender( canvas:Canvas ) Override

		App.RequestRender()

		canvas.Clear( New Color(0,0,0,1) )

		'Rotate the parent object to show that the child stays relative
		GameObject.Rotate(0.05)
		'Update the game object
		GameObject.Update()
		'Render the game object
		GameObject.Render(canvas)
	End

End

Function Main()

	New AppInstance

	New MyWindow

	App.Run()
End